home *** CD-ROM | disk | FTP | other *** search
/ Clickx 115 / Clickx 115.iso / software / tools / windows / tails-i386-0.16.iso / live / filesystem.squashfs / usr / share / perl5 / Date / Parse.pm < prev   
Encoding:
Perl POD Document  |  2010-01-14  |  8.7 KB  |  383 lines
  1. # Copyright (c) 1995-2009 Graham Barr. This program is free
  2. # software; you can redistribute it and/or modify it under the same terms
  3. # as Perl itself.
  4.  
  5. package Date::Parse;
  6.  
  7. require 5.000;
  8. use strict;
  9. use vars qw($VERSION @ISA @EXPORT);
  10. use Time::Local;
  11. use Carp;
  12. use Time::Zone;
  13. use Exporter;
  14.  
  15. @ISA = qw(Exporter);
  16. @EXPORT = qw(&strtotime &str2time &strptime);
  17.  
  18. $VERSION = "2.30";
  19.  
  20. my %month = (
  21.     january        => 0,
  22.     february    => 1,
  23.     march        => 2,
  24.     april        => 3,
  25.     may        => 4,
  26.     june        => 5,
  27.     july        => 6,
  28.     august        => 7,
  29.     september    => 8,
  30.     sept        => 8,
  31.     october        => 9,
  32.     november    => 10,
  33.     december    => 11,
  34.     );
  35.  
  36. my %day = (
  37.     sunday        => 0,
  38.     monday        => 1,
  39.     tuesday        => 2,
  40.     tues        => 2,
  41.     wednesday    => 3,
  42.     wednes        => 3,
  43.     thursday    => 4,
  44.     thur        => 4,
  45.     thurs        => 4,
  46.     friday        => 5,
  47.     saturday    => 6,
  48.     );
  49.  
  50. my @suf = (qw(th st nd rd th th th th th th)) x 3;
  51. @suf[11,12,13] = qw(th th th);
  52.  
  53. #Abbreviations
  54.  
  55. map { $month{substr($_,0,3)} = $month{$_} } keys %month;
  56. map { $day{substr($_,0,3)}   = $day{$_} }   keys %day;
  57.  
  58. my $strptime = <<'ESQ';
  59.  my %month = map { lc $_ } %$mon_ref;
  60.  my $daypat = join("|", map { lc $_ } reverse sort keys %$day_ref);
  61.  my $monpat = join("|", reverse sort keys %month);
  62.  my $sufpat = join("|", reverse sort map { lc $_ } @$suf_ref);
  63.  
  64.  my %ampm = (
  65.     'a' => 0,  # AM
  66.     'p' => 12, # PM
  67.     );
  68.  
  69.  my($AM, $PM) = (0,12);
  70.  
  71. sub {
  72.  
  73.   my $dtstr = lc shift;
  74.   my $merid = 24;
  75.  
  76.   my($year,$month,$day,$hh,$mm,$ss,$zone,$dst,$frac);
  77.  
  78.   $zone = tz_offset(shift) if @_;
  79.  
  80.   1 while $dtstr =~ s#\([^\(\)]*\)# #o;
  81.  
  82.   $dtstr =~ s#(\A|\n|\Z)# #sog;
  83.  
  84.   # ignore day names
  85.   $dtstr =~ s#([\d\w\s])[\.\,]\s#$1 #sog;
  86.   $dtstr =~ s/,/ /g;
  87.   $dtstr =~ s#($daypat)\s*(den\s)?\b# #o;
  88.   # Time: 12:00 or 12:00:00 with optional am/pm
  89.  
  90.   return unless $dtstr =~ /\S/;
  91.   
  92.   if ($dtstr =~ s/\s(\d{4})([-:]?)(\d\d?)\2(\d\d?)(?:[-Tt ](\d\d?)(?:([-:]?)(\d\d?)(?:\6(\d\d?)(?:[.,](\d+))?)?)?)?(?=\D)/ /) {
  93.     ($year,$month,$day,$hh,$mm,$ss,$frac) = ($1,$3-1,$4,$5,$7,$8,$9);
  94.   }
  95.  
  96.   unless (defined $hh) {
  97.     if ($dtstr =~ s#[:\s](\d\d?):(\d\d?)(:(\d\d?)(?:\.\d+)?)?(z)?\s*(?:([ap])\.?m?\.?)?\s# #o) {
  98.       ($hh,$mm,$ss) = ($1,$2,$4);
  99.       $zone = 0 if $5;
  100.       $merid = $ampm{$6} if $6;
  101.     }
  102.  
  103.     # Time: 12 am
  104.     
  105.     elsif ($dtstr =~ s#\s(\d\d?)\s*([ap])\.?m?\.?\s# #o) {
  106.       ($hh,$mm,$ss) = ($1,0,0);
  107.       $merid = $ampm{$2};
  108.     }
  109.   }
  110.     
  111.   if (defined $hh and $hh <= 12 and $dtstr =~ s# ([ap])\.?m?\.?\s# #o) {
  112.     $merid = $ampm{$1};
  113.   }
  114.  
  115.  
  116.   unless (defined $year) {
  117.     # Date: 12-June-96 (using - . or /)
  118.     
  119.     if ($dtstr =~ s#\s(\d\d?)([\-\./])($monpat)(\2(\d\d+))?\s# #o) {
  120.       ($month,$day) = ($month{$3},$1);
  121.       $year = $5 if $5;
  122.     }
  123.     
  124.     # Date: 12-12-96 (using '-', '.' or '/' )
  125.     
  126.     elsif ($dtstr =~ s#\s(\d+)([\-\./])(\d\d?)(\2(\d+))?\s# #o) {
  127.       ($month,$day) = ($1 - 1,$3);
  128.  
  129.       if ($5) {
  130.     $year = $5;
  131.     # Possible match for 1995-01-24 (short mainframe date format);
  132.     ($year,$month,$day) = ($1, $3 - 1, $5) if $month > 12;
  133.     return if length($year) > 2 and $year < 1901;
  134.       }
  135.     }
  136.     elsif ($dtstr =~ s#\s(\d+)\s*($sufpat)?\s*($monpat)# #o) {
  137.       ($month,$day) = ($month{$3},$1);
  138.     }
  139.     elsif ($dtstr =~ s#($monpat)\s*(\d+)\s*($sufpat)?\s# #o) {
  140.       ($month,$day) = ($month{$1},$2);
  141.     }
  142.     elsif ($dtstr =~ s#($monpat)([\/-])(\d+)[\/-]# #o) {
  143.       ($month,$day) = ($month{$1},$3);
  144.     }
  145.  
  146.     # Date: 961212
  147.  
  148.     elsif ($dtstr =~ s#\s(\d\d)(\d\d)(\d\d)\s# #o) {
  149.       ($year,$month,$day) = ($1,$2-1,$3);
  150.     }
  151.  
  152.     $year = $1 if !defined($year) and $dtstr =~ s#\s(\d{2}(\d{2})?)[\s\.,]# #o;
  153.  
  154.   }
  155.  
  156.   # Zone
  157.  
  158.   $dst = 1 if $dtstr =~ s#\bdst\b##o;
  159.  
  160.   if ($dtstr =~ s#\s"?([a-z]{3,4})(dst|\d+[a-z]*|_[a-z]+)?"?\s# #o) {
  161.     $dst = 1 if $2 and $2 eq 'dst';
  162.     $zone = tz_offset($1);
  163.     return unless defined $zone;
  164.   }
  165.   elsif ($dtstr =~ s#\s([a-z]{3,4})?([\-\+]?)-?(\d\d?):?(\d\d)?(00)?\s# #o) {
  166.     my $m = defined($4) ? "$2$4" : 0;
  167.     my $h = "$2$3";
  168.     $zone = defined($1) ? tz_offset($1) : 0;
  169.     return unless defined $zone;
  170.     $zone += 60 * ($m + (60 * $h));
  171.   }
  172.  
  173.   if ($dtstr =~ /\S/) {
  174.     # now for some dumb dates
  175.     if ($dtstr =~ s/^\s*(ut?|z)\s*$//) {
  176.       $zone = 0;
  177.     }
  178.     elsif ($dtstr =~ s#\s([a-z]{3,4})?([\-\+]?)-?(\d\d?)(\d\d)?(00)?\s# #o) {
  179.       my $m = defined($4) ? "$2$4" : 0;
  180.       my $h = "$2$3";
  181.       $zone = defined($1) ? tz_offset($1) : 0;
  182.       return unless defined $zone;
  183.       $zone += 60 * ($m + (60 * $h));
  184.     }
  185.  
  186.     return if $dtstr =~ /\S/o;
  187.   }
  188.  
  189.   if (defined $hh) {
  190.     if ($hh == 12) {
  191.       $hh = 0 if $merid == $AM;
  192.     }
  193.     elsif ($merid == $PM) {
  194.       $hh += 12;
  195.     }
  196.   }
  197.  
  198.   $year -= 1900 if defined $year && $year > 1900;
  199.  
  200.   $zone += 3600 if defined $zone && $dst;
  201.   $ss += "0.$frac" if $frac;
  202.  
  203.   return ($ss,$mm,$hh,$day,$month,$year,$zone);
  204. }
  205. ESQ
  206.  
  207. use vars qw($day_ref $mon_ref $suf_ref $obj);
  208.  
  209. sub gen_parser
  210. {
  211.  local($day_ref,$mon_ref,$suf_ref,$obj) = @_;
  212.  
  213.  if($obj)
  214.   {
  215.    my $obj_strptime = $strptime;
  216.    substr($obj_strptime,index($strptime,"sub")+6,0) = <<'ESQ';
  217.  shift; # package
  218. ESQ
  219.    my $sub = eval "$obj_strptime" or die $@;
  220.    return $sub;
  221.   }
  222.  
  223.  eval "$strptime" or die $@;
  224.  
  225. }
  226.  
  227. *strptime = gen_parser(\%day,\%month,\@suf);
  228.  
  229. sub str2time
  230. {
  231.  my @t = strptime(@_);
  232.  
  233.  return undef
  234.     unless @t;
  235.  
  236.  my($ss,$mm,$hh,$day,$month,$year,$zone) = @t;
  237.  my @lt  = localtime(time);
  238.  
  239.  $hh    ||= 0;
  240.  $mm    ||= 0;
  241.  $ss    ||= 0;
  242.  
  243.  my $frac = $ss - int($ss);
  244.  $ss = int $ss;
  245.  
  246.  $month = $lt[4]
  247.     unless(defined $month);
  248.  
  249.  $day  = $lt[3]
  250.     unless(defined $day);
  251.  
  252.  $year = ($month > $lt[4]) ? ($lt[5] - 1) : $lt[5]
  253.     unless(defined $year);
  254.  
  255.  return undef
  256.     unless($month <= 11 && $day >= 1 && $day <= 31
  257.         && $hh <= 23 && $mm <= 59 && $ss <= 59);
  258.  
  259.  my $result;
  260.  
  261.  if (defined $zone) {
  262.    $result = eval {
  263.      local $SIG{__DIE__} = sub {}; # Ick!
  264.      timegm($ss,$mm,$hh,$day,$month,$year);
  265.    };
  266.    return undef
  267.      if !defined $result
  268.         or $result == -1
  269.            && join("",$ss,$mm,$hh,$day,$month,$year)
  270.                  ne "595923311169";
  271.    $result -= $zone;
  272.  }
  273.  else {
  274.    $result = eval {
  275.      local $SIG{__DIE__} = sub {}; # Ick!
  276.      timelocal($ss,$mm,$hh,$day,$month,$year);
  277.    };
  278.    return undef
  279.      if !defined $result
  280.         or $result == -1
  281.            && join("",$ss,$mm,$hh,$day,$month,$year)
  282.                  ne join("",(localtime(-1))[0..5]);
  283.  }
  284.  
  285.  return $result + $frac;
  286. }
  287.  
  288. 1;
  289.  
  290. __END__
  291.  
  292.  
  293. =head1 NAME
  294.  
  295. Date::Parse - Parse date strings into time values
  296.  
  297. =head1 SYNOPSIS
  298.  
  299.     use Date::Parse;
  300.     
  301.     $time = str2time($date);
  302.     
  303.     ($ss,$mm,$hh,$day,$month,$year,$zone) = strptime($date);
  304.  
  305. =head1 DESCRIPTION
  306.  
  307. C<Date::Parse> provides two routines for parsing date strings into time values.
  308.  
  309. =over 4
  310.  
  311. =item str2time(DATE [, ZONE])
  312.  
  313. C<str2time> parses C<DATE> and returns a unix time value, or undef upon failure.
  314. C<ZONE>, if given, specifies the timezone to assume when parsing if the
  315. date string does not specify a timezone.
  316.  
  317. =item strptime(DATE [, ZONE])
  318.  
  319. C<strptime> takes the same arguments as str2time but returns an array of
  320. values C<($ss,$mm,$hh,$day,$month,$year,$zone)>. Elements are only defined
  321. if they could be extracted from the date string. The C<$zone> element is
  322. the timezone offset in seconds from GMT. An empty array is returned upon
  323. failure.
  324.  
  325. =back
  326.  
  327. =head1 MULTI-LANGUAGE SUPPORT
  328.  
  329. Date::Parse is capable of parsing dates in several languages, these include
  330. English, French, German and Italian.
  331.  
  332.     $lang = Date::Language->new('German');
  333.     $lang->str2time("25 Jun 1996 21:09:55 +0100");
  334.  
  335. =head1 EXAMPLE DATES
  336.  
  337. Below is a sample list of dates that are known to be parsable with Date::Parse
  338.  
  339.  1995:01:24T09:08:17.1823213           ISO-8601
  340.  1995-01-24T09:08:17.1823213
  341.  Wed, 16 Jun 94 07:29:35 CST           Comma and day name are optional 
  342.  Thu, 13 Oct 94 10:13:13 -0700
  343.  Wed, 9 Nov 1994 09:50:32 -0500 (EST)  Text in ()'s will be ignored.
  344.  21 dec 17:05                          Will be parsed in the current time zone
  345.  21-dec 17:05
  346.  21/dec 17:05
  347.  21/dec/93 17:05
  348.  1999 10:02:18 "GMT"
  349.  16 Nov 94 22:28:20 PST 
  350.  
  351. =head1 LIMITATION
  352.  
  353. Date::Parse uses L<Time::Local> internally, so is limited to only parsing dates
  354. which result in valid values for Time::Local::timelocal. This generally means dates
  355. between 1901-12-17 00:00:00 GMT and 2038-01-16 23:59:59 GMT
  356.  
  357. =head1 BUGS
  358.  
  359. When both the month and the date are specified in the date as numbers
  360. they are always parsed assuming that the month number comes before the
  361. date. This is the usual format used in American dates.
  362.  
  363. The reason why it is like this and not dynamic is that it must be
  364. deterministic. Several people have suggested using the current locale,
  365. but this will not work as the date being parsed may not be in the format
  366. of the current locale.
  367.  
  368. My plans to address this, which will be in a future release, is to allow
  369. the programmer to state what order they want these values parsed in.
  370.  
  371. =head1 AUTHOR
  372.  
  373. Graham Barr <gbarr@pobox.com>
  374.  
  375. =head1 COPYRIGHT
  376.  
  377. Copyright (c) 1995-2009 Graham Barr. This program is free
  378. software; you can redistribute it and/or modify it under the same terms
  379. as Perl itself.
  380.  
  381. =cut
  382.  
  383.